Bezdráťák stanice - minimalistická verze

(aktualizace 21.5.2025)

Programy zdarma, Arduino návody, tratě pro Open Rails a MSTS.

Ovladač k bezdráťáku zůstává původní, ale ve stanici jsem namísto Arduino MEGA, nebo UNO použil desku s procesorem STM8S103F3. Arduino IDE podporuje i tento procesor (knihovna SDuino), ale nakonec jsem se rozhodnul sáhnout k vývojovému prostředí výrobce STMicroelectronics a pokusil jsem se oprášit své určité zkušenosti s assemblerem z dávných dob.
Na desce modulu není rozhraní pro nahrání programu do paměti ROM, k tomu slouží externí programátor ST-Link V2. Výhodou zde je debug mód, díky kterému program lze krokovat a sledovat obsah registrů a paměti. Konektor USB mikro, který je na modulu, může sloužit pouze pro napájení 5V.

Propojení těchto tří modulů je velmi jednoduché, viz schéma výše. Pro stažení většího rozlišení jako PDF soubor klikněte zde.
Chtěl jsem zachovat možnost ovládat hlasitost potenciometrem na stanici, aniž bych použil nějaký nf zesilovač připojený na sluchátkový výstup zvukového modulu BT201. Dal jsem tedy potenciometr přímo na výkonový výstup modulu BT201. Potenciometr má trochu netypickou hodnotu 100R (menší jsem nesehnal). Koupit se dá zde. Reproduktor je galvanicky oddělen od jezdce potenciometru kondenzátorem 100u. Reproduktor se samozřejmě dá připojit přímo k výkonovému výstupu BT201 (piny SPK). Potenciometr, ani výstupní kondenzátor pak není potřeba a hlasitost se reguluje pouze ovladačem.
Zdroják níže jsem se pokusil okomentovat podrobněji, pokud by se někdo chtěl v něm vrtat, ať se v tom alepoň trochu vyzná. K přeložení však samotný zdroják nestačí, je potřeba stáhnout složku projektu, kde jsou ještě dva malé vygenerované soubory.

Zdrojový kod stanice náhled (STM8S103F3) stáhnout projekt.

stm8/

              .form 64
              .tab 10,8,18,60
               TITLE "Bezdratak - minimalisticka verze"

              #include "mapping.inc"

ram0_start.b   equ  $ram0_segment_start
ram0_end.b     equ  $ram0_segment_end
ram1_start.w   equ  $ram1_segment_start
ram1_end.w     equ  $ram1_segment_end	
stack_start.w  equ  $stack_segment_start 
stack_end.w    equ  $stack_segment_end

WIFI_KANAL     equ  81    ; 2402 + 81 = 2483 
PKT_MAXLEN     equ  61    ; delka pakety
SEND_MAXLEN    equ  64
BUFFER_LEN     equ  80    ; delka bufferu
CLK_CKDIVR     equ  $50C6 ; Clock divider register

;registry GPIO 
PA_ODR         equ  $5000 ; Port A data output
PA_IDR         equ  $5001 ; Port A input pin value register
PA_DDR         equ  $5002 ; Port A data direction register
PA_CR1         equ  $5003 ; Port A control register 1
PA_RESET       equ  1     ; LT8920 reset pin
PA_PKT         equ  2     ; LT8920 data priznak
PA_CS          equ  3     ; chip select - pin 3 = PA3/D2/SS
PB_ODR         equ  $5005 ; interni LED, neni nutne
PB_DDR         equ  $5007 ; 
PB_CR1         equ  $5008 ; 
PB_LED         equ  5  

;registry UART1
UART_SR        equ  $5230 ; status register
UART_DR        equ  $5231 ; data register
UART_BRR1      equ  $5232 ; baud rate register 1
UART_BRR2      equ  $5233 ; baud rate register 2
UART_CR1       equ  $5234 ; control register 1
UART_CR2       equ  $5235 ; control register 2

;registry SPI
SPI_CR1        equ  $5200 ; SPI control register 1
SPI_CR2        equ  $5201 ; SPI control register 2
SPI_SR         equ  $5203 ; SPI status register
SPI_DR         equ  $5204 ; SPI data register

;registry TIMER2
TIM_CR1        equ  $5300
TIM_SR1        equ  $5304 ; status register 1
TIM_ARRH       equ  $530F ; auto-reload value na 31250
TIM_ARRL       equ  $5310 ; interrupt interval
TIM_PSCR       equ  $530E ; prescaler pro delani
TIM_IER        equ  $5303 ; povoleni interrupt

;registry LT8920                          
LT_KANAL       equ  7
LT_VYKON       equ  9     ; power + gain
LT_PKT_CFG     equ  41    ; konfig pakety
LT_RATE        equ  44    ; ruchlost 1MB/sec
LT_STATUS      equ  48
LT_FIFO        equ  50
LT_FIFO_CTRL   equ  52
LT_SYNC1       equ  36    ; ID 16 x 4 bitu, neco jako adresa, modul se bavi 
LT_SYNC2       equ  37    ; s jinym modulem, pouze pokud ma stejnou ID
LT_SYNC3       equ  38
LT_SYNC4       equ  39

              .page
;--------------------------------------------------------------
               segment 'ram1'
               
dump           ds.b
uart_rx_cnt    ds.b                
uart_buffer    ds.b    BUFFER_LEN  ;uart rx buffer               
wifi_rx_cnt    ds.b                
wifi_buffer    ds.b    BUFFER_LEN  ;wifi 2.4GHz buffer
rxwait         ds.b
temp           ds.b
               
               segment 'rom'
               
;---INIT-------------------------------------------------------

main.l        ;initialize sys
               mov   CLK_CKDIVR, #$00	   ;cpu rychlost
               sim
               ldw   X, #stack_end
               ldw   SP, X

               ldw   X, #ram0_start
clear_ram0.l
               clr   (X)
               incw  X
               cpw   X, #ram0_end	
               jrule clear_ram0

               ldw   X, #ram1_start
clear_ram1.l
               clr  (X)
               incw  X
               cpw   X, #ram1_end	
               jrule clear_ram1	            

               ldw   X, #stack_start
clear_stack.l  
               clr  (X)
               incw  X
               cpw   X, #stack_end	
               jrule clear_stack
       
               clr   dump             
               call  DELAY_1000

               .page       

;---SETUP------------------------------------------------------

SETUP          ;GPIO
               bset  PA_DDR, #PA_CS    ;pin 3 PA3/D2/SS output
               bset  PA_CR1, #PA_CS    ;pin 3 PA3/D2/SS push-pull mode
               bset  PA_ODR, #PA_CS    ;pin 3 PA3/D2/SS high
               bset  PA_DDR, #PA_RESET 
               bset  PA_CR1, #PA_RESET
               bset  PA_ODR, #PA_RESET ;high, low evokuje reset LT8900
               bres  PA_DDR, #PA_PKT
               bset  PA_CR1, #PA_PKT
               bset  PB_DDR, #PB_LED   ;pouziti interni LED neni nutne
               bset  PB_CR1, #PB_LED
               bset  PB_ODR, #PB_LED

               ;UART1
               mov   UART_BRR2, #$03  ;baud rate 9600 bd, BRR2 musi byt prvni
               mov   UART_BRR1, #$68
               bset  UART_CR2,#3	     ;povoli TX
               bset  UART_CR2,#2	     ;povoli RX

               ;SPI  MODE1: CPOL=0, CPHA=1
               mov   SPI_CR2, #3       ; SSM + SSI
               mov   SPI_CR1, #$18     ; rychlost - divider 28=master/64, 18=master/16
               bset  SPI_CR1, #2       ; SPI master mode
               bset  SPI_CR1, #0       ; CPHA=1
               bset  SPI_CR1, #6       ; povoli SPI

               ldw   X, #atcz            ;reset BT201
               ld    A, (X)              ;prvni byte je delka
               incw  X
               mov   rxwait, #32        ;delsi cas na odpoved
               call  UART_CMD

               bres  PA_ODR, #PA_RESET   ;reset LT8920
               call  DELAY_500
               bset  PA_ODR, #PA_RESET
               call  DELAY_1000
               ldw   X, #lt_begin        ;init hodnoty LT8920
               ld    A, (X)              ;smycka zapisuje do registru LT8920
               ld    temp, A             ;cislo registru
lt_loop        incw  X
               ld    A, (X)
               ld    YH, A               ;MSB
               incw  X
               ld    A, (X)
               ld    YL, A               ;LSB
               ld    A, temp
               call  WRITE_REG           ;a zapis
               call  DELAY_100
               incw  X
               ld    A, (X)              ;cislo dalsiho registru
               ld    temp, A
               cp    A, #$87
               jrne  lt_loop

               ldw   Y, #$0100          ;rychlost 1MBS nizsi na LT8920 nefunguji
               ld    A, #LT_RATE
               call  WRITE_REG

               ldw   Y, #$0080          ;nejaka doporucena hodnota
               ld    A, #45
               call  WRITE_REG
               call  DELAY_500

               ldw   Y, #WIFI_KANAL     ;kanal 2402 + X, zde kanal 2483
               ld    A, #LT_KANAL       
               call  WRITE_REG

               mov   rxwait, #16         ;init prehravace MP3 BT201
               call  DELAY_500
               ldw   X, #atck            ;nenajizdet bluetooth automaticky
               ld    A, (X)
               incw  X
               call  UART_CMD
               call  DELAY_500
               ldw   X, #atca            ;hlasitost
               ld    A, (X)
               incw  X
               call  UART_CMD

               call  DELAY_500
               mov   rxwait, #3
    
              .page


;---LOOP (hlavni smycka}---------------------------------------

infinite_loop.l
               callr UART_FLUSH        ;vycisti uart
               ldw   X, #wifi_buffer   ;vycisti buffery
               call  CLEAR_BUFFER
               ldw   X, #uart_buffer
               call  CLEAR_BUFFER
               call  LISTEN

wifi_test      btjt  PA_IDR, #PA_PKT, rcv
               callr UART_FLUSH        ;zde je uart ingnorovan
               jra   wifi_test         ;cekej paketu z wifi 
               
rcv            call  FIFO_RX           ;prisla paketa z wifi
               jrnc  rcv_ok            ;byla nejaka chyba prenosu?
               jra   infinite_loop     ; ano, znovu

rcv_ok         callr UART_FLUSH
               call  CMD_TEST          ;natahne i adresu bufferu
               jrc   infinite_loop     ;pokud nezacina na AT+
               ld    A, wifi_rx_cnt    ;pocet prijatych byte
               callr UART_CMD
               ld    A, uart_rx_cnt    ;poslat odpoved na wifi
               ldw   X, #wifi_buffer
               call  FIFO_TX
               jra   infinite_loop
               
;--------------UART--------------------------------------------

UART_FLUSH ;[18] zahodi prichozi data
flush_rx       btjf  UART_SR, #5, retrn_18
               mov   dump, UART_DR
               nop
               jra   flush_rx
retrn_18       ret

UART_CMD  ;[12] prikaz BT201, v X je prikaz, v A delka, v rxwait cas na odpoved
skip_12        callr UART_TX      ;poslat AT prikaz
               nop
repe_12        btjf  UART_SR, #5, repe_12 ;cekej odpoved
               callr UART_RX      ;precist odpoved do uart_buffer
               ret

UART_RX  ;[1] prijme znaky a uklada na uart_buffer v uart_rx_cnt vrati pocet
               mov   temp, rxwait    ;v rxwait je pocet cyklu cekani
               ldw   X, #uart_buffer
               clr   uart_rx_cnt     ;pocitadlo prijatych znaku
repe_1         ld    A, UART_DR  
               ld   (X), A
               ld    A, uart_rx_cnt  ;zarazka
               cp    A, #BUFFER_LEN
               jruge skip_1
               inc   uart_rx_cnt     ;zvysi pocet a index
               incw  X
skip_1         btjt  UART_SR, #5, repe_1  ;dalsi znak k dispozici?
skip_1b        ldw   Y, #$7fff            ;  ne, ale jeste vyckej
repe_1a        decw  Y                    ;  u prijmu byvaji prodlevy
               jrv   repe_1b
               btjf  UART_SR, #5, repe_1a
               jra   repe_1
repe_1b        dec   temp
               jreq  retrn_1
               jra   repe_1a 
retrn_1        ld    A, uart_rx_cnt
               jreq  skip_1a              ;nulova delka ? 
               call  COPY_RX
skip_1a        ret
							 
UART_TX  ;[2] odesle znaky, z adresy X, pocet je v A
               ld    temp, A               ;ulozi pocet k odeslani
repe_2         btjf  UART_SR, #7, repe_2   ;cekat na prazdny TX registr
               ld    A, (X)
  						       ld    UART_DR, A
               incw  X
               ld    A, temp
               dec   A
               jrsle retrn_2 
               ld    temp, A
							        jra   repe_2
retrn_2        btjf  UART_SR, #7, retrn_2 ;nakonec posle CRLF
               mov   UART_DR, #13
repe_2b        btjf  UART_SR, #7, repe_2b
               mov   UART_DR, #10
repe_2c        btjf  UART_SR, #7, repe_2c
repe_2a        btjf  UART_SR, #6, repe_2a ;cekat na transfer complete
               ret

;---LT8920-----------------------------------------------------

SPI_TRAN   ;[3] posle hodnotu v A a precte hodnotu do A
               ld    SPI_DR, A
wait_sent      btjf  SPI_SR, #1, wait_sent ;cekej na odeslani
               nop
wait_recv      btjf  SPI_SR, #0, wait_recv  ;cekej na precteni               
               ld    A, SPI_DR
               ret

READ_REG  ;[4] precte registr ulozeny v A, hodnotu vrati v Y (mimo FIFO)
               bres  PB_ODR, #PB_LED    
               bres  PA_ODR, #PA_CS     ;pin 3 low
               or    A, #$80            ;nahodit priznak cteni
               callr SPI_TRAN           ;pozadovany registr
               push  A
               clr   A
               callr SPI_TRAN           ;precte prvni byte MSB
               ld    YH, A              ;MSB
               clr   A
               callr SPI_TRAN           ;precte druhy byte LSB
               ld    YL, A            
               bset  PA_ODR, #PA_CS     ;pin 3 high
               bset  PB_ODR, #PB_LED
               pop   A
               ret

WRITE_REG ;[5] zapise do registru A, hodnotu Y (mimo FIFO)
               bres  PB_ODR, #PB_LED
               bres  PA_ODR, #PA_CS     ;pin 3 low
               and   A, #$7f            ;shodit priznak cteni (zapis)
               callr SPI_TRAN           ;pozadovany registr
               push  A
               ld    A, YH
               callr SPI_TRAN           ;zapise prvni byte MSB
               ld    A, YL
               callr SPI_TRAN             ;zapise druhy byte LSB
               bset  PA_ODR, #PA_CS     ;pin 3 high
               bset  PB_ODR, #PB_LED
               pop   A
               ret

LISTEN    ;[6] prepne do modu pro prijem dat
               ldw   Y, #WIFI_KANAL     ;shodi rx i tx
               ld    A, #LT_KANAL       
               callr WRITE_REG
               call  DELAY_5
               ldw   Y, #$0080          ;vyprazdni rx
               ld    A, #LT_FIFO_CTRL
               callr WRITE_REG
               call  DELAY_5
               ldw   Y, #WIFI_KANAL     ;nastavi kanal + rx mod
               ld    A, YL
               or    A, #$80            ;priznak rx
               ld    YL, A
               ld    A, #LT_KANAL       
               callr WRITE_REG
               call  DELAY_20
               ret

FIFO_RX    ;[7] prijem dat FIFO, nacte do bufferu X
               ldw   X, #wifi_buffer
               clr   wifi_rx_cnt
               ld    A, #LT_STATUS
               call  READ_REG
               ld    A, YH 
               ld    temp, A
               btjt  temp, #7, crc_err
               ld    A, #LT_FIFO
               call  READ_REG           ;zjisteni delky pakety
               ld    A, YH
               jreq  crc_err            ;nulova delka?
               ld    temp, A
               cp    A, #PKT_MAXLEN
               jruge crc_err            ;nespravna delka
               mov   wifi_rx_cnt, temp  ;ulozi delku 
               ld    A, YL              ;ulozi prvni byte
               ld   (X), A
loop_7         incw  X
               ld    A, #LT_FIFO
               call  READ_REG
               ld    A, YH
               ld   (X), A
               incw  X
               ld    A, YL
               ld   (X), A
next_7         dec   temp               ;precte vzdy dva byte (word)               
               dec   temp
               rcf                      ;shodi pripadny carry flag
               jrsle retrn_7            ;vse precteno
               jra   loop_7
crc_err        scf                       ;u crc error, nahodi carry flag
retrn_7        btjt  SPI_SR, #7, retrn_7 ;celej dokud je busy
               ret

FIFO_TX    ;[8] odeslani dat FIFO, odesle data z bufferu X, pocet v A
               cp    A, #PKT_MAXLEN
               jrule skip_8a
               ld    A, #PKT_MAXLEN
skip_8a        inc   A
               or    A, #1            ;lichy pocet
               ld    temp, A          ;uloz pocet
               ldw   Y, #WIFI_KANAL
               ld    A, #LT_KANAL
               call  WRITE_REG        ;flush TX 
               call  DELAY_5
               ldw   Y, #$8000        ;prejdi na vysilani
               ld    A, #LT_FIFO_CTRL
               call  WRITE_REG   
               call  DELAY_5
               ld    A, temp
               ld    YH, A            ;posle delku
               ld    A, (X)
               ld    YL, A            ;a prvni byte
               ld    A, #LT_FIFO
               call  WRITE_REG   
               call  DELAY_5
               dec   temp
loop_8         incw  X
               ld    A, (X)           ;nahraj na fifo
               ld    YH, A
               incw  X
               ld    A, (X)
               ld    YL, A
skip_8         ld    A, #LT_FIFO
               call  WRITE_REG
               dec   temp
               dec   temp
               jrsle retrn_8
               jra   loop_8
retrn_8        call  DELAY_5
               ldw   Y, #WIFI_KANAL    ;odesli fifo
               ld    A, #1             ;priznak tx
               ld    YH, A
               ld    A, #LT_KANAL
               call  WRITE_REG
wait_8         btjf  PA_IDR, #PA_PKT, wait_8
               call  DELAY_20
               ret

;--------------------------------------------------------------

CLEAR_BUFFER ;[14] v X je adresa pocet je BUFFER_LEN
               pushw X
               ld    A, #32
               mov    dump, #BUFFER_LEN
repe_14        ld  (X), A
               incw  X
               dec   dump
               jrne  repe_14
               popw  X
               ret

COPY_RX  ;[11] prefiltruje prijate znaky z uartu do wifi bufferu
               clr   temp
               clr   dump
               ldw   X, #uart_buffer
               ldw   Y, #wifi_buffer
repe_11        ld    A, (X) 
               and   A, #$7f 
               cp    A, #'.'           ;po tecce test, co nasleduje
               jrne  skip_11f
               callr is_ext            ;priponu nebrat
               jrc   retrn_11
skip_11f       cp    A, #32            ;zapamatuj mezeru
               jrne  skip_11e
               mov   dump, #1
skip_11e       cp    A, #'_'           ;nebo podtrzitko
               jrne  skip_11c
               mov   dump, #1
skip_11c       cp    A, #'-'           ;nebo pomlcku
               jrne  skip_11a
               mov   dump, #1
skip_11a       cp    A, #10            
               jreq  save_char         ;LF je povolen jako oddelovac
               cp    A, #'+'
               jreq  save_char         ;plus je povoleo
               cp    A, #122           ;znaky nad chr(122) neukladat
               jrugt skip_11
               cp    A, #48            ;od cislic nize neukladat
               jrslt skip_11
               cp    A, #58            ;cislice ok
               jrslt save_char
               cp    A, #65            ;carky, stredniky, pomlcky.. nebrat
               jrslt skip_11
               cp    A, #91            ;velka pismena ok
               jrslt char_ok
               cp    A, #97            ;lomitka, zavorky.. nebrat
               jrslt skip_11
char_ok        tnz   dump              ;predchazela mezera?
               jreq  skip_11b          ;  ne
               and   A, #$5F           ;  ano, dej upper case
               jra   save_char
skip_11b       or    A, #$20           ;lower case
save_char      ld   (Y), A
               clr   dump
               inc   temp
               incw  Y
skip_11        incw  X
               dec   uart_rx_cnt
               jrne  repe_11
retrn_11       rcf
               mov   uart_rx_cnt, temp
               ld    A, wifi_buffer    ;prvni znak bude upper case
               and   A, #$5F
               ld    wifi_buffer, A
               ret

is_ext         pushw X                 ;test pripony MP3
               push  A
               incw  X
               ld    A, (X)
               and   A, #$5F           ;upper case
               cp    A, #'M'
               jrne  retrn_15
               incw  X
               cp    A, #'P'
               jrne  retrn_15
               scf                     ;ano je MP, nahod carry flag
retrn_15       pop   A
               popw  X
               ret

CMD_TEST  ;[17] kazdy prikaz musi zacit na AT+
               ldw   X, #wifi_buffer
               ld    A, (X)
               cp    A, #'A'
               jrne  retrn_17err
               ld    A, ($1,X)
               cp    A, #'T'
               jrne  retrn_17err
               ld    A, ($2,X)
               cp    A, #'+'
               jrne  retrn_17err
               rcf
               jra   retrn_17
retrn_17err    scf
retrn_17       ret 

;---DELAY---(1 / 2000000) * 32 * X-----------------------------

DELAY_5    ;
               mov     TIM_ARRH, #$05
               mov     TIM_ARRL, #$0a
               mov     TIM_PSCR, #5
               callr   delay_irq
               ret

DELAY_20   ;(1 / 2000000) * 32 * 1290
               mov     TIM_ARRH, #$05
               mov     TIM_ARRL, #$0a
               mov     TIM_PSCR, #5
               callr   delay_irq
               ret

DELAY_100  ;(1 / 2000000) * 32 * 6450
               mov     TIM_ARRH, #$19
               mov     TIM_ARRL, #$32
               mov     TIM_PSCR, #5
               callr   delay_irq
               ret

DELAY_500  ;(1 / 2000000) * 32 * 31250
               mov     TIM_ARRH, #$7A
               mov     TIM_ARRL, #$12
               mov     TIM_PSCR, #5
               callr   delay_irq
               ret

DELAY_1000  ;2 x 500 
               callr   DELAY_500
               callr   DELAY_500
               ret

delay_irq      bset    TIM_CR1, #0  ; povol timer
               bset    TIM_IER, #0
               wfi
               ret 

;--------------------------------------------------------------

	             interrupt timer_interrupt
timer_interrupt.l
               bres    TIM_SR1, #0  ;update interrupt flag
               bres    TIM_IER, #0  ;zakaze dalsi tiknuti
               iret

	             interrupt NonHandledInterrupt
NonHandledInterrupt.l
               iret

;---konstanty--------------------------------------------------

               ;nastaveni BT201 po zapnuti
atcz           dc.b   5, "AT+CZ"     ;reset
atck           dc.b   7, "AT+CK00"   ;nenajizdet bluetooth automaticky
atca           dc.b   7, "AT+CA18"   ;hlasitost 

               ;nastaveni LT8920 ve smycce "lt_loop" --> registr, MSB, LSB, ...
lt_begin       dc.b   0, $6f, $e0, 1, $56, $81, 2, $66, $17, 4, $9c, $c9 
               dc.b   5, $66, $37, 8, $6c, $90
               dc.b   LT_VYKON, $84, $00 ; vykon a uroven modulace
               dc.b   10, $7f, $fd, 11, $00, $00, 12, $00, $00, 13, $48, $bd
               dc.b   22, $00, $ff, 23, $80, $05, 24, $00, $67, 25, $16, $59
               dc.b   26, $19, $e0, 27, $13, $00, 28, $18, $00, 32, $50, $00
               dc.b   33, $3f, $c7, 34, $20, $00, 35, $0f, $00
               dc.b   LT_SYNC1, $12, $3D ; ID = 123A 123B 123C 123D
               dc.b   LT_SYNC2, $12, $3C
               dc.b   LT_SYNC3, $12, $3B
               dc.b   LT_SYNC4, $12, $3A
               dc.b   40, $44, $01, 
               dc.b   LT_PKT_CFG, $b0, $00
               dc.b   42, $fd, $b0, 43, $00, $0f
               dc.b   LT_FIFO, $00, $00, LT_FIFO_CTRL, $80, $80  ;fifo reset
               dc.b   $87 ; ukoncovak
version_no     dc.l   $88888888
               dc.l   $00000000
               dc.l   $33333333
               dc.l   $eeeeeeee

              .page
;--------------------------------------------------------------
	             segment 'vectit'
               
	dc.l {$82000000+main}									; reset
	dc.l {$82000000+NonHandledInterrupt}	; trap
	dc.l {$82000000+NonHandledInterrupt}	; irq0
	dc.l {$82000000+NonHandledInterrupt}	; irq1
	dc.l {$82000000+NonHandledInterrupt}	; irq2
	dc.l {$82000000+NonHandledInterrupt}	; irq3
	dc.l {$82000000+NonHandledInterrupt}	; irq4
	dc.l {$82000000+NonHandledInterrupt}	; irq5
	dc.l {$82000000+NonHandledInterrupt}	; irq6
	dc.l {$82000000+NonHandledInterrupt}	; irq7
	dc.l {$82000000+NonHandledInterrupt}	; irq8
	dc.l {$82000000+NonHandledInterrupt}	; irq9
	dc.l {$82000000+NonHandledInterrupt}	; irq10
	dc.l {$82000000+NonHandledInterrupt}	; irq11
	dc.l {$82000000+NonHandledInterrupt}	; irq12
	dc.l {$82000000+timer_interrupt}     ; irq13 (TIMER2)
	dc.l {$82000000+NonHandledInterrupt}	; irq14
	dc.l {$82000000+NonHandledInterrupt}	; irq15
	dc.l {$82000000+NonHandledInterrupt}	; irq16
	dc.l {$82000000+NonHandledInterrupt}	; irq17
	dc.l {$82000000+NonHandledInterrupt} ; irq18
	dc.l {$82000000+NonHandledInterrupt}	; irq19
	dc.l {$82000000+NonHandledInterrupt}	; irq20
	dc.l {$82000000+NonHandledInterrupt}	; irq21
	dc.l {$82000000+NonHandledInterrupt}	; irq22
	dc.l {$82000000+NonHandledInterrupt}	; irq23
	dc.l {$82000000+NonHandledInterrupt}	; irq24
	dc.l {$82000000+NonHandledInterrupt}	; irq25
	dc.l {$82000000+NonHandledInterrupt}	; irq26
	dc.l {$82000000+NonHandledInterrupt}	; irq27
	dc.l {$82000000+NonHandledInterrupt}	; irq28
	dc.l {$82000000+NonHandledInterrupt}	; irq29

	end

aktualizováno 21.5.2025

Co je potřeba:
Především procesorová deska STM8S103F3. K nahrání kódu do ní je třeba programátor ST-Link V2. Pro jeho připojení postupujte podle tohoto návodu, je v něm i odkaz na stažení příslušného ovladače (st_link driver).
Dále musíte stáhnout vývojové prostředí ST Visual develop k přeložení projektu. Tento software je free, akorát si pravděpodobně vyžádají Váš e-mail.

Po nainstalování:

rozbalte stažený projekt do libovolné složky.
spusťe ST Visual develop ([Program files]\STMicroelectronics\st_toolset\stvd\stvdebug.exe")
jděte v hlavním menu na File -> Open workspace a otevřte projekt (uartMP3.stw) v rozbalené složce.
jako cíl zvolte na toolbaru release
zvolte v hlavním menu Build -> Build tím se projekt přeloží
nakonec v hlavním menu vyberte Debug -> Start debugging tím se program nahraje do modulu (případně jej můžete spustit i krokovat).

Snad jsem tímto alespoň trochu demonstroval jak pracovat s UARTem, či se sběrnicí SPI v STM8 assembleru u tohoto procesoru. Netvrdím, že je tento způsob je dokonalý, k assebleru jsem se teď vrátil po opravdu dlouhé době. Pokud někdo má nějaké náměty na vylepšení, budu rád, když použíje formulář níže.
(v osmdesátých letech minulého století jsem pracoval na výpočetním středisku patřícím ČSD (Československé státní dráhy) na sálovém počítači EC-8540 alias KA-10 a jiný jazyk, než assembler jsme k dispozoci neměli).

Programy zdarma, Arduino návody, tratě pro Open Rails a MSTS.

Vzkazník - dotazy, názory, připominky, hlášení chyb, atd:
jméno (e-mail): E-mail nebude nikde zveřejněn, uveďte jej, pouze pokud si přejete odpověď.
text: